文章/答案/技术大牛

发布

问Pollard Rho在APL中的实现
EN

Stack Overflow用户

提问于 2014-09-18 04:33:10

回答 1查看 162关注 0票数 1

最近，我试图使用APL工作，但在概念化它方面遇到了困难。例如，假设我想编写一个程序g<-pollard x，其中该函数通过Pollard-Rho方法计算数字x是否为素数或可因式分解。

我知道这个方法本身，但我不知道从哪里开始将它真正集成到APL中。我应该从创建一个全新的函数f(x)开始，还是应该在代码中包含所有内容？我该如何保存上一次运行的x，以便在下一次运行中使用？请注意，我并不是要求一个完整的程序，只是一些建议，让我开始。

primes

apl

回答 1

Stack Overflow用户

发布于 2014-09-18 11:05:27

首先，对于尝试一门你不懂的语言来说，这是一件微不足道的事情。尽管如此，我发现这个问题很有趣，并为您提供了几个解决方案。这些都是使用Dyalog APL完成的。对于APL新手来说，他们需要一些学习。

第一个解决方案是Pollard Rho的一个简单函数(由维基百科定义)，将f(x)直接嵌入到main函数中：

PollardRho←{
     n←⍵
     ⍺←2 2 1
     x y d←⍺
     f←{n|1+⍵*2}
     x←f x
     y←f f y
     d←n∨|x-y
     d=n:'Failure'
     d≠1:d
     x y d ∇ n
 }

我们可以在APL会话中尝试一下：

     PollardRho 8051
97

第二种方法从main函数中提取函数f(x)，并将其作为参数提供，这便于对f(x)使用不同的函数。在APL中，将函数作为参数的函数称为运算符：

PollardRho2←{
     n←⍵
     ⍺←2 2 1
     x y d←⍺
     x←n ⍺⍺ x
     y←n ⍺⍺ n ⍺⍺ y
     d←n∨|x-y
     d=n:'Failure'
     d≠1:d
     x y d ⍺⍺ ∇∇ n
 }

通过首先定义函数f(x)并将其作为左操作数提供，我们可以在会话中运行此函数：

      f←{⍺|1+⍵*2}
      f PollardRho2 8051
97

请注意，这两种解决方案都使用尾递归。

我希望这对你有用。

票数 4

页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持

原文链接：

https://stackoverflow.com/questions/25899857

复制

相似问题

问Pollard Rho在APL中的实现
EN

回答 1

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问Pollard Rho在APL中的实现EN

回答 1

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问Pollard Rho在APL中的实现
EN