文章/答案/技术大牛

发布

社区首页 >问答首页 >相当于削减-f1-3,5在awk

问相当于削减-f1-3,5在awk
EN

Stack Overflow用户

提问于 2022-09-28 18:04:25

回答 2查看 48关注 0票数 0

我要字段1,2,3,5

我用刀子做：

cut -f1-3,5

然而，对于awk，我会这样做：

awk '{for (i=0;i<=5;i++) {if (i!=4) {print $i}} }'

但我想让它更简洁。此外，在其他情况下，我可以有更多的不同距离的字段。awk '{for (i in 1 2 3 5) {print $i}}'不工作。我该怎么做？

awk

回答 2

Stack Overflow用户

回答已采纳

发布于 2022-09-28 20:55:54

这做了cut所做的事情，而且做得更多：

$ echo 'a b c d e f g' |
awk -v ranges='1-3,5' '
    BEGIN {
        split(ranges,r,/,/)
        for ( i=1; i in r; i++ ) {
            n = split(r[i],range,/-/)
            for ( j=range[1]; j<=range[n]; j++ ) {
                f[++onf] = j
            }
        }
    }
    {
        for ( i=1; i<=onf; i++ ) {
            printf "%s%s", $(f[i]), (i<onf ? OFS : ORS)
        }
    }
'
a b c e

上述假设假设，如果您多次指定相同的字段号，那么需要多次打印该字段，并且希望按指定的顺序打印字段，以便例如重新排列顺序和/或重复字段，例如：

$ echo 'a b c d e f g' |
awk -v ranges='6,1-3,5,2,1' '
    BEGIN {
        split(ranges,r,/,/)
        for ( i=1; i in r; i++ ) {
            n = split(r[i],range,/-/)
            for ( j=range[1]; j<=range[n]; j++ ) {
                f[++onf] = j
            }
        }
    }
    {
        for ( i=1; i<=onf; i++ ) {
            printf "%s%s", $(f[i]), (i<onf ? OFS : ORS)
        }
    }
'
f a b c e b a

票数 1

Stack Overflow用户

发布于 2022-09-28 18:44:23

对于按位置、数量和字段范围等进行字段选择的工作，cut做得更好。如果您真的想在awk中模仿这种行为，前提是您还需要在awk中完成其他任务，那么您可以考虑使用以下代码：

cat fcut.awk

BEGIN {
   n = split(f, a, /,/)
   for (i=1; i<=n; ++i) {
      if (split(a[i], b, /-/) == 2) {
         for (j=b[1]; j<=b[2]; ++j)
            fld[j]
      }
      else
         fld[a[i]]
   }
}
{
   for (i=1; i<=NF; ++i) {
      if (i in fld)
         s = (st++ ? s OFS : "") $i
   }
   print s
   s = st = ""
}

现在将其运行为：

awk -v f='1-3,5' -f fcut.awk file

票数 3

页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持

原文链接：

https://stackoverflow.com/questions/73886011

复制

相似问题

问相当于削减-f1-3,5在awk
EN

回答 2

Stack Overflow用户

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问相当于削减-f1-3,5在awkEN

回答 2

Stack Overflow用户

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问相当于削减-f1-3,5在awk
EN